[ESP32]新規タスクの生成方法

新しいタスクを追加する方法

新しいタスクを追加する方法

プログラムを作成していくと、新たにタスクを追加したい時がくると思います。

例えば、以下のような処理をするプログラムを作成する場合は別々のタスクで実行した方が良いと思います。

赤外線センサーで人を検知するとLEDを光らせる。
外部サーバと通信接続して検知データを送信する。

このような場合、１．は周期的に動作して赤外線センサーからの情報を読み取っていますが、２．の処理に時間を要する場合、１．の処理が待たされて人がいるのにLEDがなかなか光ってくれないかもしれません。

サンプルコード（コピペで動作）

使用API：xTaskCreatePinnedToCore() / vTaskDelete()

TaskHandle_t thp[2];
ulong count = 0;

// the setup function runs once when you press reset or power the board
void setup() {
  
  // initialize serial communication at 115200 bits per second:
  Serial.begin(115200);
  
  // Now set up two tasks to run independently.
  xTaskCreatePinnedToCore( TaskA, "TaskA", 2048, NULL, 2, &thp[0], APP_CPU_NUM);
  xTaskCreatePinnedToCore( TaskB, "TaskB", 2048, NULL, 2, &thp[1], APP_CPU_NUM);

  delay(10000);
  vTaskDelete(thp[0]);
  Serial.println("TaskA End");
  vTaskDelete(thp[1]);
  Serial.println("TaskB End");

  Serial.printf("uxTaskPriorityGet : %d\n", uxTaskPriorityGet(NULL));
  Serial.printf("xPortGetCoreID : %d\n", xPortGetCoreID());
}

void loop()
{
  // Empty. Things are done in Tasks.
}

/*--------------------------------------------------*/
/*---------------------- Tasks ---------------------*/
/*--------------------------------------------------*/
void TaskA(void *pvParameters)  // This is a task.
{
  Serial.println("TaskA Start");
  while( 1 ) {
    delay(100);
    count++;
  }
  // ここにはこないが明示的にタスク終了を記載しておく。
  vTaskDelete(NULL);
}

void TaskB(void *pvParameters)  // This is a task.
{
  Serial.println("TaskB Start");
  while( 1 ) {
    Serial.printf("TaskB : %d\n", count);
    delay(1000);
  }
  // ここにはこないが明示的にタスク終了を記載しておく。
  vTaskDelete(NULL);
}

上記サンプルコードでは、メインタスクが11行目,12行目でTaskAとTaskBを生成し、10秒後に15行目,17行目でTaskAとTaskBを削除しています。

xTaskCreatePinnedToCore(引数)

pxTaskCode	タスクの関数ポインタ
pcName	タスク名称（ユーザーのためのタスク名称）
usStackDepth	スタックサイズ(bytes) （1024,2048,4096などで指定）
pvParameters	タスク生成時に渡すパラメータが格納されるポインタ（渡すものがなければNULLでよい）
uxPriority	タスク優先度（0～24）（数字が大きくなるほど優先度高）
pvCreatedTask	生成したタスクハンドル（必要なければNULLでもよい）
xCoreID	コアID （PRO_CPU_NUM (0)　APP_CPU_NUM (1)）